How to Calculate Percentage Change in Google Sheets

By Gerard Fernandez · Updated · 2 min read

Percentage change tells you how much a value grew or shrank compared with before: sales this month versus last month, a price now versus a year ago. The formula is always the same.

The formula

=(new - old) / old

With last month's sales in B2 and this month's in B3:

=(B3-B2)/B2

The result is a decimal, like 0.125. Select the cells and click the % button on the toolbar (or Format → Number → Percent) to show it as 12.50%.

Google Sheets sales of 800, 900, 720 and 936 with month-on-month change 12.50%, -20.00% and 30.00%; C4 shows the formula =(B4-B3)/B3
Real test: 800 → 900 is +12.50%, 900 → 720 is −20.00%, 720 → 936 is +30.00%. Positive results are increases and negative results are decreases.

Type the formula in C3 and drag it down: each row compares that month with the month above.

Other common versions

You want…Formula
Change compared with a fixed starting value in B2=(B3-$B$2)/$B$2
The new value after a 15% increase=B2*(1+15%)
The new value after a 15% discount=B2*(1-15%)
Built-in function (same value, no decimals shown)=TO_PERCENT((B3-B2)/B2)

We checked these in the same sheet: with 800 in B2, the 15% increase gave 920 and the discount 680. TO_PERCENT showed 13% rather than 12.50%, because it displays no decimals. Click Increase decimal places if you need them.

Avoid #DIV/0! when the old value is 0

Growth from zero can't be expressed as a percentage, so the formula returns #DIV/0!. Show a blank instead:

=IF(B2=0, "", (B3-B2)/B2)

More in how to fix #DIV/0!.

Color increases green and decreases red

Select the results and add two conditional formatting rules: Greater than 0 with green text and Less than 0 with red text.

Other percentage formulas

Google Sheets has no special percentage function: a percentage is one number divided by another, shown with the % format (Format → Number → Percent).

You want…Formula
Share of a total=C3/SUM($C$3:$C$7)
Add 10%=A2*(1+10%)
Subtract 25% (a discount)=A2*(1-25%)
15% of a number=A2*15%

Don't multiply by 100. The % format already does it: =C3/C8*100 formatted as percent shows 3314% instead of 33.14%.

Frequently asked questions

Why does my result show 1250% instead of 12.5%?

You probably multiplied by 100 and then applied the % format, which multiplies again. In our test, =(B3-B2)/B2*100 formatted as percent showed 1250.00%. Use either *100 or the % format, not both.

What's the difference between percentage change and percentage of a total?

Percentage change compares two values over time. Percentage of a total shows one part's share, like =B2/SUM(B2:B10). See how to calculate percentages.